commit 86cfa6c27f989bca3c18399a27a276645352100c
author Manuel Pégourié-Gonnard <manuel.pegourie-gonnard@arm.com> Fri May 14 10:07:33 2021 +0200
committer David Horstmann <david.horstmann@arm.com> Mon Oct 25 13:16:03 2021 +0100
tree ab2d1d3d8504b9801a0af8c9948bd1c263c4e5f2
parent 3a8413d3165af9b84859ca9e935ad4a183c2622c

Allow CMake to generate query_config.c

This one was trickier for two reasons:

1. It's used from another directory, see
https://gitlab.kitware.com/cmake/community/-/wikis/FAQ#how-can-i-add-a-dependency-to-a-source-file-which-is-generated-in-a-subdirectory

2. The C file being generated after CMake is run means CMake can't
automatically scan for included headers and do its usual magic, so we
need to declare the dependency and more importantly the include path.

Signed-off-by: Manuel Pégourié-Gonnard <manuel.pegourie-gonnard@arm.com>

programs/ssl/CMakeLists.txt

diff --git a/programs/ssl/CMakeLists.txt b/programs/ssl/CMakeLists.txt
index bdce56b..a14e264 100644
--- a/programs/ssl/CMakeLists.txt
+++ b/programs/ssl/CMakeLists.txt
@@ -18,17 +18,32 @@
     ssl_server2
 )
 
+# Inform CMake the the following file will be generated as part of the build
+# process, so it doesn't complain that it doesn't exist yet. Starting from
+# CMake 3.20, this will no longer be necessary as CMake will automatically
+# propagate this information accross the tree, for now it's only visible
+# inside the same directory, so we need to propagate manually.
+set_source_files_properties(
+    ${CMAKE_CURRENT_BINARY_DIR}/../test/query_config.c
+    PROPERTIES GENERATED TRUE)
+
 foreach(exe IN LISTS executables)
     set(extra_sources "")
     if(exe STREQUAL "ssl_client2" OR exe STREQUAL "ssl_server2")
         list(APPEND extra_sources
             ssl_test_lib.c
-            ${CMAKE_CURRENT_SOURCE_DIR}/../test/query_config.c)
+            ${CMAKE_CURRENT_SOURCE_DIR}/../test/query_config.h
+            ${CMAKE_CURRENT_BINARY_DIR}/../test/query_config.c)
     endif()
     add_executable(${exe} ${exe}.c $<TARGET_OBJECTS:mbedtls_test>
         ${extra_sources})
     target_link_libraries(${exe} ${libs})
     target_include_directories(${exe} PRIVATE ${CMAKE_CURRENT_SOURCE_DIR}/../../tests/include)
+    if(exe STREQUAL "ssl_client2" OR exe STREQUAL "ssl_server2")
+        add_dependencies(${exe} generate_query_config_c)
+        target_include_directories(${exe}
+            PRIVATE ${CMAKE_CURRENT_SOURCE_DIR}/../test)
+    endif()
 endforeach()
 
 if(THREADS_FOUND)

programs/test/CMakeLists.txt

diff --git a/programs/test/CMakeLists.txt b/programs/test/CMakeLists.txt
index a0a1b76..8193124 100644
--- a/programs/test/CMakeLists.txt
+++ b/programs/test/CMakeLists.txt
@@ -27,15 +27,40 @@
     target_link_libraries(cpp_dummy_build ${mbedcrypto_target})
 endif()
 
+find_package(Perl REQUIRED)
+
+add_custom_command(
+    OUTPUT
+        ${CMAKE_CURRENT_BINARY_DIR}/query_config.c
+    COMMAND
+        ${PERL}
+            ${CMAKE_CURRENT_SOURCE_DIR}/../../scripts/generate_query_config.pl
+            ${CMAKE_CURRENT_SOURCE_DIR}/../../include/mbedtls/mbedtls_config.h
+            ${CMAKE_CURRENT_SOURCE_DIR}/../../scripts/data_files/query_config.fmt
+            ${CMAKE_CURRENT_BINARY_DIR}/query_config.c
+    DEPENDS
+        ${CMAKE_CURRENT_SOURCE_DIR}/../../scripts/generate_query_config.pl
+        ${CMAKE_CURRENT_SOURCE_DIR}/../../include/mbedtls/mbedtls_config.h
+        ${CMAKE_CURRENT_SOURCE_DIR}/../../scripts/data_files/query_config.fmt
+)
+# this file will also be used in anoter directory, so create a target, see
+# https://gitlab.kitware.com/cmake/community/-/wikis/FAQ#how-can-i-add-a-dependency-to-a-source-file-which-is-generated-in-a-subdirectory
+add_custom_target(generate_query_config_c
+    DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/query_config.c)
+
 foreach(exe IN LISTS executables_libs executables_mbedcrypto)
     set(extra_sources "")
     if(exe STREQUAL "query_compile_time_config")
         list(APPEND extra_sources
-            ${CMAKE_CURRENT_SOURCE_DIR}/query_config.c)
+            ${CMAKE_CURRENT_SOURCE_DIR}/query_config.h
+            ${CMAKE_CURRENT_BINARY_DIR}/query_config.c)
     endif()
     add_executable(${exe} ${exe}.c $<TARGET_OBJECTS:mbedtls_test>
         ${extra_sources})
     target_include_directories(${exe} PRIVATE ${CMAKE_CURRENT_SOURCE_DIR}/../../tests/include)
+    if(exe STREQUAL "query_compile_time_config")
+        target_include_directories(${exe} PRIVATE ${CMAKE_CURRENT_SOURCE_DIR})
+    endif()
 
     # This emulates "if ( ... IN_LIST ... )" which becomes available in CMake 3.3
     list(FIND executables_libs ${exe} exe_index)